MerDB

The team declares the part trove in its own file. Each index row is an access path the store keeps up to date on every write. bySerial stores a lowercased key, so P-204 and p-204 can never both exist.

# _db/troves/part.tri
trove part {
    text<class=ascii> serial = ""
    text unitId = ""
    text status = "ready"
    timepoint<unix> changedAt = now()
    unique index bySerial = t.text.ascii.lower(serial)
    index byChangedAt = changedAt
    index byUnitStatus = [unitId, status]
}

The board asks its question along byChangedAt. The call names the index, two bounds and a limit, and the store reads only the key range between them. The answer is newest first and never longer than 500 ids.

u64[] changedSince(timepoint<unix> shiftStart) {
    chest lower = { timepoint<unix> inclusive = shiftStart }
    chest upper = { timepoint<unix> inclusive = t.clock.now() }
    return t.db.range("part", "byChangedAt", lower, upper, true, 500)
}

text board() {
    timepoint<unix> shiftStart = t.time.unix.add(t.clock.now(), 0s - 8h)
    text lines = ""
    foreach (id in changedSince(shiftStart)) {
        chest row = t.db.get("part", id)
        chest doc = row.document
        text serial = doc.serial
        text status = doc.status
        lines = lines + serial + " " + status + "\n"
    }
    return lines
}

A technician marks P-204 installed. The update is conditional on the fields it names. If another technician changed status after this one read it, the volume primary refuses the write and the program takes its else arm.

text install(part p) {
    transaction {
        part.update(p, { status = "installed", changedAt = t.clock.now() })
    } else (f) {
        fault reason = f.reason
        if (reason == fault.store_conflict) {
            return "changed by another technician; reload and retry"
        }
        return "not saved"
    }
    return "installed"
}

The reorder desk follows the change feed. poll reads a page of events without moving anything, and ack moves the desk’s cursor past what it handled. An event names a record and its version, never its contents, so the desk reads each record under its own read access.

u64 drainOnce(u64 savedThrough) {
    resource<t.db.subscription> feed = t.db.subscribe("part", savedThrough)
    chest page = t.db.poll("part", feed, 64)
    chest[] changes = page.events
    foreach (change in changes) {
        u64 id = change.id
        u8 deleted = change.deleted
        if (deleted == 0) {
            chest row = t.db.get("part", id)
            chest doc = row.document
            text status = doc.status
            if (status == "installed") {
                t.log.info("reorder stock for part " + text(id))
            }
        }
    }
    u64 through = page.through
    t.db.ack("part", feed, through)
    t.db.unsubscribe("part", feed)
    return through
}